statusbar — u_pbt_statusbar #

← Komponentenreferenz · Inhalt des Handbuchs

Statusleiste aus Bereichen: Rich-Text, Symbole, feste oder automatische Breiten, Ausrichtung nach links oder rechts, anklickbare Bereiche, ein Mini-Fortschrittsbalken und farbige Zustände.

▶ Live ansehen — Demoanwendung, Kachel Statusbar: die Vorschau, der zugehörige Code und diese Seite, nebeneinander.

Auf einen Blick #

Schnellstart #

// open-Event des Fensters
// of_add_panel(id, Text, Symbol, Ausrichtung, Breite)
// leere id = rein informativer Bereich ; Breite 0 = an den Text angepasst
uo_statut.of_add_panel(/*id*/ "etat",  /*text*/ "Bereit",           /*icon_file*/ "", /*align*/ uo_statut.ALIGN_START,  /*width*/ 0)
uo_statut.of_add_panel(/*id*/ "",      /*text*/ "Zeile 12, Sp. 4", /*icon_file*/ "", /*align*/ uo_statut.ALIGN_START,  /*width*/ 0)
uo_statut.of_add_panel(/*id*/ "heure", /*text*/ "12:00",          /*icon_file*/ "", /*align*/ uo_statut.ALIGN_END, /*width*/ 140)

// Einen Bereich jederzeit ueber seinen Bezeichner aktualisieren
uo_statut.of_item("etat").is_text = "Wird gespeichert..."

Das Modell: Bereiche mit Schlüssel #

Die Leiste ist eine Folge von Bereichen, die der Reihe nach hinzugefügt werden. Ein Bereich erhält bei der Erstellung einen Bezeichner: Über ihn finden Sie ihn später wieder, um seinen Text, sein Symbol oder seinen Zustand zu ändern.

Der Bezeichner ist ein Adressierungsschlüssel, kein Schalter für Interaktivität:

• Bezeichner angegeben: das Panel ist wiederauffindbar — man ändert seinen Inhalt, man gibt ihm einen Tooltip. Es bleibt reglos: eine Statusleiste zeigt vor allem an, und ein Panel wie Zeile 12, Sp. 4 darf nicht drückbar wirken.
• Leerer Bezeichner: das Panel ist rein dekorativ. Es ist weder auffindbar noch anklickbar, und es lässt sich kein Tooltip daran hängen. Geben Sie jedem Panel einen Bezeichner: das kostet nichts und hält die Tür offen.
• Um ein Panel anklickbar zu machen, verlangen Sie es: of_item("id").ib_clickable = true. Ein Panel mit einer Auswahlliste (of_set_panel_menu) ist es bereits.

uo_statut.of_item("etat").is_text = "3 Datensaetze geaendert"

Siehe Gemeinsame Basis · Die Items.

Eigenschaften #

Methoden #

Die Argumente von of_add_panel #

Auf einem Bereich — n_pbt_statusbar_panel #

Zustandskonstanten #

Wie bei jeder Eigenschaft mit vordefinierten Werten sollten Sie die Konstante statt der Zeichenkette verwenden:

n_pbt_statusbar_panel lnv_panneau
lnv_panneau = uo_statut.of_item("etat")
lnv_panneau.is_state = lnv_panneau.STATE_WARNING

Events #

Über die Tastatur #

Die Leiste ist ein einziger Tabulatorstopp: nur die zum Anklicken gedachten Felder gehören dazu, und die Pfeile durchlaufen sie.

Ein Feld, das nur anzeigt, ist kein Steuerelement: es ist weder fokussierbar noch wird es als solches angesagt. Ein anklickbares, aber deaktiviertes Feld bleibt dagegen als nicht verfügbar angesagt, statt für Text gehalten zu werden. Ein Fortschrittsbalken sagt seinen Wert an, ein unbestimmter keinen — dieses Fehlen ist die Bedeutung des Wortes.

Der Fokus übersteht den Neuaufbau der Leiste: sie wird bei jeder Textänderung neu gezeichnet, und ohne dies fiele der Fokus bei einer Leiste mit Uhr jede Sekunde weg.

Beispiele #

Feste und automatische Breiten #

// Breite 0 : der Bereich nimmt genau den Platz seines Textes ein
uo_statut.of_add_panel(/*id*/ "", /*text*/ "An den Inhalt angepasster Bereich", /*icon_file*/ "", /*align*/ uo_statut.ALIGN_START, /*width*/ 0)

// Feste Breite in Pixeln : nuetzlich, wenn sich der Text haeufig aendert,
// damit die benachbarten Bereiche nicht bei jeder Aktualisierung springen
uo_statut.of_add_panel(/*id*/ "pos", /*text*/ "Zeile 1, Sp. 1", /*icon_file*/ "", /*align*/ uo_statut.ALIGN_START, /*width*/ 150)

// Ein Bereich, der ans entgegengesetzte Ende geschoben wird
uo_statut.of_add_panel(/*id*/ "heure", /*text*/ "12:00", /*icon_file*/ "", /*align*/ uo_statut.ALIGN_END, /*width*/ 140)

Symbole und anklickbare Bereiche #

// Ein nicht leerer Bezeichner macht den Bereich anklickbar
uo_statut.of_add_panel(/*id*/ "save", /*text*/ "Gespeichert", /*icon_file*/ "mono:img\save.svg", /*align*/ uo_statut.ALIGN_START, /*width*/ 0)
uo_statut.of_add_sep()   // Trennlinie zwischen zwei Gruppen von Bereichen
uo_statut.of_add_panel(/*id*/ "conn", /*text*/ "Verbunden",   /*icon_file*/ "mono:img\plug.svg", /*align*/ uo_statut.ALIGN_START, /*width*/ 0)
uo_statut.of_add_panel(/*id*/ "user", /*text*/ "Guillaume",  /*icon_file*/ "mono:img\user.svg", /*align*/ uo_statut.ALIGN_END, /*width*/ 160)

// Event ue_panel_clicked von uo_statut
choose case as_id
    case "conn" ; open(w_parametres_connexion)
    case "user" ; open(w_profil)
end choose

Rich-Text in einem Bereich #

Die Bereiche akzeptieren die Rich-Text-Auszeichnung: Stile, Farben und kleine Bilder direkt im Text.

uo_statut.of_add_panel(/*id*/ "", /*text*/ "Willkommen [b]bei[/b] [accent]PBToolboxAI[/accent]", &
                       /*icon_file*/ "", /*align*/ uo_statut.ALIGN_START, /*width*/ 0)

uo_statut.of_add_panel(/*id*/ "", /*text*/ "[green]Online[/green] [picture=mono:img\plug.svg,14,14]", &
                       /*icon_file*/ "", /*align*/ uo_statut.ALIGN_END, /*width*/ 0)

// Rich-Text gilt auch fuer Aktualisierungen
uo_statut.of_item("etat").is_text = "[b]" + String(ll_modifies) + "[/b] Datensaetze geaendert"

Einen langen Vorgang verfolgen #

n_pbt_statusbar_panel lnv_avance

uo_statut.of_add_panel(/*id*/ "import", /*text*/ "Import", /*icon_file*/ "", /*align*/ uo_statut.ALIGN_START, /*width*/ 220)
lnv_avance = uo_statut.of_item("import")

// In der Verarbeitungsschleife : der Mini-Balken folgt dem Fortschritt
lnv_avance.ii_progress = ll_pourcentage
lnv_avance.is_text     = "Import " + String(ll_pourcentage) + " %"

// Am Ende : den Mini-Balken ausblenden und das Ergebnis melden
lnv_avance.ii_progress = -1                       // negativer Wert = Balken ausgeblendet
lnv_avance.is_text     = "Import abgeschlossen"
lnv_avance.is_state    = lnv_avance.STATE_SUCCESS

Einen dezenten Hinweis melden #

n_pbt_statusbar_panel lnv_panneau
lnv_panneau = uo_statut.of_item("conn")

if not ib_connecte then
    lnv_panneau.is_text  = "Offline"
    lnv_panneau.is_state = lnv_panneau.STATE_ERROR
else
    lnv_panneau.is_text  = "Verbunden"
    lnv_panneau.is_state = lnv_panneau.STATE_NONE   // zurueck zum normalen Erscheinungsbild
end if

Die Leiste an den Kontext anpassen #

// Einen Bereich ausblenden, ohne ihn zu loeschen : er findet seinen Platz spaeter wieder
uo_statut.of_item("user").ib_visible = ib_utilisateur_identifie

// Ihn ausgrauen, wenn die zugehoerige Aktion keinen Sinn ergibt
uo_statut.of_item("save").ib_enabled = ib_document_ouvert

// Neu anordnen : den Zustandsbereich an den Anfang stellen (Positionen ab 0 gezaehlt)
uo_statut.of_move_panel(/*id*/ "etat", /*index*/ 0)

// Einen ueberfluessig gewordenen Bereich entfernen
uo_statut.of_remove_panel(/*id*/ "import")

Der Größenänderungsgriff #

// Bei einem Fenster mit veraenderbarer Groesse ist der Eckgriff ein vertrauter Anhaltspunkt
uo_statut.ib_show_resize_grip = true

Best Practices #

• Geben Sie Bereichen, deren Text sich häufig ändert (Cursorposition, Zähler), eine feste Breite: Die benachbarten Bereiche springen dann nicht mehr bei jeder Aktualisierung.
• Lassen Sie den Bezeichner bei einem rein informativen Bereich leer: Das vermeidet einen Klick ohne Wirkung.
• Halten Sie die rechte Seite für stabile Informationen frei (Uhrzeit, Benutzer, Verbindung) und die linke Seite für den aktuellen Kontext.
• Verwenden Sie is_state statt Farben im Text: Der Zustand folgt sowohl dem hellen als auch dem dunklen Design.
• Denken Sie daran, is_state wieder auf STATE_NONE und ii_progress wieder auf einen negativen Wert zu setzen, sobald der Hinweis oder der Vorgang beendet ist.
• Eine Statusleiste ist kein Protokoll: Ab fünf oder sechs Bereichen ist eine toaster-Benachrichtigung vorzuziehen.
• Wenn der Fortschritt mehr verdient als einen Mini-Balken in einem Bereich, wechseln Sie zur progressbar.

← Komponentenreferenz · Inhalt des Handbuchs