restclient — n_pbt_restclient #

← Riferimento dei componenti · Sommario della guida

Un client HTTPS per PowerBuilder, versione 10 compresa: GET, POST, PUT, PATCH, DELETE, intestazioni, un corpo JSON, il download di un file. Nativo — TLS, proxy e decompressione del sistema, e nessun muro CORS, perché la richiesta non parte da una pagina.

▶ Vederlo dal vivo — Applicazione dimostrativa, riquadro REST client: le risposte, il codice che le ottiene e questa pagina, fianco a fianco (connessione Internet richiesta).

In breve #

Avvio rapido #

// Local variables
n_pbt_restclient lnv_rest
n_pbt_json lnv_j
long ll_status

// One client for the API : its address and the token it sends
lnv_rest = create n_pbt_restclient
lnv_rest.is_base_url = "https://api.example.com"
lnv_rest.of_set_bearer(/*token*/ ls_token)

// Read : the status comes back, the body waits in the object
ll_status = lnv_rest.of_get(/*url*/ "/orders/4152")
if ll_status = 200 then ls_customer = lnv_rest.of_json_value(/*path*/ "customer")

// Create : the body is built with n_pbt_json, never by hand
lnv_j.of_set_number(/*path*/ "order", /*value*/ 4152)
lnv_j.of_set_string(/*path*/ "status", /*value*/ "shipped")
ll_status = lnv_rest.of_post(/*url*/ "/shipments", /*body*/ lnv_j.of_text())
if ll_status < 0 then MessageBox("API", lnv_rest.is_last_error)

// The client is no longer needed
destroy lnv_rest

Ogni metodo HTTP restituisce lo stato scelto dal server — un 404 è una risposta, non un errore — oppure un codice negativo quando la richiesta non è andata a buon fine: -5 URL o intestazione non validi, certificato client non trovato, -4 fallimento (nessuna rete, nome sconosciuto, tempo scaduto, TLS, un corpo di testo oltre 64 MB — 16 MB in un processo a 32 bit; is_last_error dice quale), -6 rifiutato in modalità demo.

Perché nativo, e non la pagina #

Un fetch() lanciato da una pagina della libreria è soggetto a CORS: ogni API che non invia Access-Control-Allow-Origin gli è chiusa, e le API aziendali non lo inviano. La richiesta parte quindi dalla DLL, tramite WinHTTP: il TLS del sistema con i suoi certificati, il proxy configurato, gzip. Ciò che perdi: nulla; ciò che guadagni: tutte le API.

Proprietà #

Costanti: METHOD_GET, METHOD_POST, METHOD_PUT, METHOD_PATCH, METHOD_DELETE per of_request.

Metodi #

Esempi #

Leggere un elenco e scorrerlo #

// Local variables
string ls_body, ls_id
n_pbt_json lnv_list
long ll_i

// One value : of_json_value("items/1/id"). The whole list : load the body into an
// n_pbt_json and walk it by path.
if lnv_rest.of_get(/*url*/ "/orders?status=open") = 200 then
	ls_body = lnv_rest.of_response_text()
	lnv_list.of_load(/*json*/ ls_body)
	for ll_i = 1 to lnv_list.of_count(/*path*/ "items")
		ls_id = lnv_list.of_get_string(/*path*/ "items/" + String(ll_i) + "/id")
	next
end if

Scaricare un documento #

// Local variables
long ll_status

// Download the invoice to a file, then open it
ll_status = lnv_rest.of_download(/*url*/ "/orders/4152/invoice.pdf", /*path*/ "C:\temp\invoice-4152.pdf")
if ll_status = 200 then
	Run("C:\temp\invoice-4152.pdf")
elseif ll_status < 0 then
	MessageBox("Download", lnv_rest.is_last_error)
end if

Un'API che risponde con un errore #

// The status decides : 200 or 201 = created, 401 = the token expired,
// below 0 = the network failed
choose case lnv_rest.of_post(/*url*/ "/shipments", /*body*/ ls_body)
	case 200, 201
	case 401
		MessageBox("API", "Token expired : " + lnv_rest.of_json_value(/*path*/ "message"))
	case is < 0
		MessageBox("Network", lnv_rest.is_last_error)
end choose

Un'API dell'intranet con autenticazione Windows #

// Local variables
n_pbt_restclient lnv_rest
long ll_status

// An IIS API of the intranet : the Windows session answers the server's challenge,
// nothing is typed. Off by default : switch it on for this client only.
lnv_rest = create n_pbt_restclient
lnv_rest.is_base_url = "https://erp.intranet.local/api"
lnv_rest.ib_windows_auth = true

// A header refused (a line break in the value) returns -5 and is not set
if lnv_rest.of_set_header(/*name*/ "X-Client", /*value*/ "PowerBuilder") < 0 then return

// Read an order : 401 when the server refused the Windows account
ll_status = lnv_rest.of_get(/*url*/ "/orders/4152")
if ll_status = 401 then
	MessageBox("ERP", "Access denied")
elseif ll_status < 0 then
	MessageBox("ERP", lnv_rest.is_last_error)
end if

// The client is no longer needed
destroy lnv_rest

Asincrono (senza bloccare l'interfaccia) #

Durante una chiamata sincrona l'interfaccia è bloccata fino alla risposta: la finestra non si ridisegna più e non risponde più ai clic. Per una chiamata breve non ha conseguenze; per ogni chiamata che può durare — un server lento, un corpo grande, una rete incerta —, usa l'API asincrona: la richiesta parte su un thread di lavoro e la sua risposta torna più tardi come evento. Sincrono e asincrono condividono la stessa sessione: il cookie impostato da un login sincrono serve alle chiamate asincrone che seguono, e viceversa; una chiamata sincrona non attende mai dietro le richieste asincrone dello stesso oggetto.

Preparazione — niente da collegare: il componente consegna da solo la risposta in ue_response. of_open / of_close aprono e chiudono il client (facoltativo: la prima richiesta lo apre), of_clear_cookies dimentica i cookie conservati tra una richiesta e l'altra. Internamente, una pompa del componente chiama of_process_events per drenare le risposte — non la chiami mai.

Inviare — of_request_async(method, url, body), o le scorciatoie of_get_async, of_post_async, of_put_async, of_patch_async, of_delete_async, restituiscono subito un id di richiesta — oppure -5 subito, senza alcun evento dopo, per un URL o un'intestazione non validi (is_last_error dice perché, per esempio «invalid URL: …»). Al massimo sei richieste partono insieme; le successive attendono il loro turno in una coda. of_download_async(url, path) scarica in un file e of_upload(url, field, path) invia un file in multipart/form-data — entrambi con avanzamento. of_cancel(id) ferma una richiesta. I tentativi (il_max_retries, il_retry_backoff_ms) ripetono su 429/503/guasto di rete.

Ricevere — ue_response(al_id, al_status) (leggere il corpo con of_response_text(al_id) / of_status(al_id) DENTRO il gestore), ue_failed(al_id, al_code, as_error), ue_progress(al_id, al_done, al_total). Un id vale solo per l'oggetto che ha inviato la richiesta. Un errore di esecuzione in uno di questi eventi non viene inghiottito: risale all'evento SystemError dell'applicazione come ogni errore di script, e le risposte successive vengono consegnate comunque.

// Async : the UI never freezes, and there is nothing to wire.
ll_id = uo_rest.of_get_async(/*url*/ "https://api.example.com/orders/4152")

// The answer arrives on its own in the ue_response event of uo_rest :
IF al_status >= 200 AND al_status < 300 THEN
	ls_body = uo_rest.of_response_text(/*id*/ al_id)
END IF

Buone pratiche #

• Un client per API, con il suo is_base_url e le sue intestazioni impostati una volta: il codice delle chiamate porta solo il percorso e il corpo.
• Il corpo si costruisce con n_pbt_json, mai per concatenazione: una virgoletta nel nome di un cliente non rompe nulla.
• Verifica lo stato, poi il codice negativo: >= 200 e < 300 va bene, >= 400 il server ha detto no, < 0 la richiesta non è partita — is_last_error dice perché.
• Il tempo limite: 30 secondi per impostazione predefinita; un report pesante ne merita di più, un controllo di presenza di meno.
• Ciò che può durare va in asincrono: una chiamata sincrona blocca l'interfaccia fino alla risposta.
• Un reindirizzamento conserva la tua richiesta: un 301 o un 302 riscrive in GET solo un POST — un PUT, un PATCH o un DELETE viene rifatto così com'è, corpo compreso; un 303 riparte in GET senza corpo. Una Location relativa (?page=2, ../) è risolta come farebbe un browser.
• Un reindirizzamento verso un altro host non porta nulla di tuo: nessuna delle intestazioni impostate da of_set_header (token, chiave API) lo segue — resta solo Content-Type. Un reindirizzamento HTTPS → HTTP è rifiutato.
• Verifica il ritorno di of_set_header, of_set_bearer e of_set_basic quando il valore viene da un input o da un file: un a capo vi è rifiutato (-5) e nulla viene impostato. Un'intestazione rifiutata non parte mai a metà.
• Le credenziali Windows partono solo se lo chiedi: ib_windows_auth = true per un'API dell'intranet con autenticazione Windows, mai su un client che parla con Internet.
• Un corpo di testo è limitato a 64 MB, 16 MB in un'applicazione a 32 bit: un export voluminoso si legge con of_download / of_download_async, che scrivono un file senza limiti.

← Riferimento dei componenti · Sommario della guida