markdownview — u_pbt_markdownview #

← Riferimento dei componenti · Sommario della guida

markdownview mostra un documento Markdown in sola lettura, con i colori del tema: titoli, elenchi, tabelle, elenchi di attività, codice colorato, immagini. Si imposta il testo in is_markdown, o il percorso di un file in is_source; un link non naviga mai, solleva ue_link_clicked e decide l'applicazione. L'HTML grezzo di un documento non viene mai eseguito.

▶ Vederlo dal vivo — Applicazione dimostrativa, tessera Markdown viewer, con il codice e questa pagina fianco a fianco.

In breve #

Avvio rapido #

// Show a Markdown file : its pictures and relative links are read against its folder
uo_md.is_source = "C:\Acme\Help\guide.md"

// ... or any text the application has
uo_md.is_markdown = "# Release notes~n~n- [x] Orders~n- [ ] Invoices"

// ue_link_clicked : the viewer never navigates, the application decides where to open as_url

Proprietà #

Metodi #

Eventi #

Esempio #

Una guida in linea che apre i suoi link #

Un documento arriva spesso da fuori: si smista in base alla natura del link, mai al suo testo. Una pagina Web o una mail si aprono nel loro programma, un altro documento si mostra nello stesso componente, e un file — un .exe, un .bat — non viene mai avviato senza chiedere.

// ue_link_clicked of uo_md : the viewer never navigates, the application decides by the kind
choose case as_kind
	case u_pbt_markdownview.LINK_WEB, u_pbt_markdownview.LINK_MAIL

		// A web page, a mail : their program
		ShellExecuteW(0, "open", as_url, "", "", 1)
	case u_pbt_markdownview.LINK_DOCUMENT

		// Another page of the help : in this viewer
		uo_md.is_source = as_url
	case else

		// A file of the disk or of the network : never run without asking
		MessageBox("Link", "This link leads to a file : " + as_url)
end choose

Modificare Markdown: un codeeditor e un markdownview #

Il visualizzatore mantiene la posizione di lettura quando il testo cambia: si modifica la fine di un documento lungo senza che l'anteprima torni in cima.

// Local variables
string ls_notes

// The notes of the customer, in Markdown
ls_notes = "# Notes~n~n- [ ] Call back on Monday"

// The editor colours Markdown ; the viewer shows the page
uo_editor.is_syntax = u_pbt_codeeditor.SYNTAX_MARKDOWN
uo_editor.is_text = ls_notes
uo_md.is_markdown = ls_notes

// ue_changed of uo_editor : the whole recipe
uo_md.is_markdown = uo_editor.is_text

Un indice in un elenco #

Per un file impostato da is_source, riempite l'elenco in ue_loaded: prima, il file è ancora in lettura.

// Local variables
string ls_titles[], ls_anchors[]
long ll_levels[], ll_i

// ue_loaded of uo_md : one line per heading, indented by its level
lb_toc.Reset()
for ll_i = 1 to uo_md.of_toc(/*titles*/ ls_titles, /*levels*/ ll_levels, /*anchors*/ ls_anchors)
	lb_toc.AddItem(Fill(" ", (ll_levels[ll_i] - 1) * 3) + ls_titles[ll_i])
next

// Local variables
string ls_titles[], ls_anchors[]
long ll_levels[]

// SelectionChanged of lb_toc : bring that heading to the top
uo_md.of_toc(/*titles*/ ls_titles, /*levels*/ ll_levels, /*anchors*/ ls_anchors)
uo_md.of_scroll_to(/*anchor*/ ls_anchors[index])

Una lista di controllo che l'utente spunta #

// Local variables
string ls_text
long ll_at, ll_n

// The user may tick the boxes of the text
uo_md.ib_tasks_editable = true

// ue_task_toggled of uo_md : the start of line al_line of the text
ls_text = uo_md.is_markdown
ll_at = 1
for ll_n = 2 to al_line
	ll_at = Pos(ls_text, "~n", ll_at) + 1
next

// Its box, the first "[" of the line, becomes [x] or [ ]
ll_at = Pos(ls_text, "[", ll_at)
if ab_checked then
	ls_text = Replace(ls_text, ll_at, 3, "[x]")
else
	ls_text = Replace(ls_text, ll_at, 3, "[ ]")
end if

// The text set back : the view keeps its place
uo_md.is_markdown = ls_text

Il componente non riscrive mai il testo da sé: l'applicazione mantiene il controllo su ciò che salva.

Riaprire un documento dove il lettore l'ha lasciato #

// Before closing the window : remember the place in the guide
SetProfileString("acme.ini", "help", "position", uo_md.is_position)

// When the guide is shown again : the place is taken once the file is on screen
uo_md.is_source = "C:\Acme\Help\guide.md"
uo_md.is_position = ProfileString("acme.ini", "help", "position", "")

Buone pratiche #

• È un lettore, non un editor: per scrivere Markdown, mettete accanto un codeeditor in SYNTAX_MARKDOWN, collegato da una riga nel suo ue_changed (vedere l'esempio); il visualizzatore mantiene la posizione quando il testo cambia.
• I link sono vostri: niente si apre da solo; ue_link_clicked dà l'indirizzo, già risolto rispetto alla cartella del file, e la sua natura (as_kind) — smistate in base a essa, mai al testo dell'indirizzo, e non avviate mai un LINK_FILE senza chiedere.
• Un documento non esegue nulla: l'HTML grezzo è mostrato come scritto (o, con ib_allow_html, solo un breve elenco di tag inerti), un link javascript: resta testo, un'immagine http:// è rifiutata, come un'immagine su una condivisione di rete (ib_network_pictures) — un documento venuto da fuori si mostra senza rischi.
• Le immagini: un percorso relativo si legge rispetto alla cartella del file (o is_base_path per un testo); per un'immagine del Web, preferite https://, o scaricatela prima (restclient.of_download) e date il suo percorso. ib_remote_pictures a false non ne carica nessuna.
• Un file si legge in background: dopo is_source, attendete ue_loaded per leggere l'indice; un'ancora e una ricerca chieste nel frattempo attendono il file.
• Un documento grande resta fluido: i primi blocchi compaiono subito, il resto negli istanti seguenti; la ricerca (al massimo 50.000 occorrenze), of_scroll_to e la stampa aspettano che sia completo.
• Da destra a sinistra: il documento segue il verso dell'applicazione (elenchi, citazioni e tabelle si capovolgono), un blocco di codice resta da sinistra a destra, e una colonna allineata dall'autore (:--, --:) mantiene il suo lato.

Ereditato dalla base comune #

Questi membri esistono su tutti i componenti visivi — non sono propri di questo. Sono descritti una sola volta, nei capitoli trasversali; questa tabella dice solo dove leggerli.

← Riferimento dei componenti · Sommario della guida