markdownview — u_pbt_markdownview #

← Referencia de componentes · Índice de la guía

markdownview muestra un documento Markdown de solo lectura, con los colores del tema: títulos, listas, tablas, listas de tareas, código coloreado, imágenes. Fija el texto en is_markdown, o la ruta de un archivo en is_source; un enlace nunca navega, lanza ue_link_clicked y decide la aplicación. El HTML en bruto de un documento nunca se ejecuta.

▶ Verlo en vivo — Aplicación de demostración, mosaico Markdown viewer, con el código y esta página lado a lado.

De un vistazo #

Inicio rápido #

// Show a Markdown file : its pictures and relative links are read against its folder
uo_md.is_source = "C:\Acme\Help\guide.md"

// ... or any text the application has
uo_md.is_markdown = "# Release notes~n~n- [x] Orders~n- [ ] Invoices"

// ue_link_clicked : the viewer never navigates, the application decides where to open as_url

Propiedades #

Métodos #

Eventos #

Ejemplo #

Una ayuda en línea que abre sus enlaces #

Un documento a menudo viene de fuera: se clasifica por la naturaleza del enlace, nunca por su texto. Una página Web o un correo se abren en su programa, otro documento se muestra en el mismo componente, y un archivo — un .exe, un .bat — nunca se ejecuta sin preguntar.

// ue_link_clicked of uo_md : the viewer never navigates, the application decides by the kind
choose case as_kind
	case u_pbt_markdownview.LINK_WEB, u_pbt_markdownview.LINK_MAIL

		// A web page, a mail : their program
		ShellExecuteW(0, "open", as_url, "", "", 1)
	case u_pbt_markdownview.LINK_DOCUMENT

		// Another page of the help : in this viewer
		uo_md.is_source = as_url
	case else

		// A file of the disk or of the network : never run without asking
		MessageBox("Link", "This link leads to a file : " + as_url)
end choose

Editar Markdown: un codeeditor y un markdownview #

El visor conserva su posición de lectura cuando el texto cambia: se edita el final de un documento largo sin que la vista previa salte arriba.

// Local variables
string ls_notes

// The notes of the customer, in Markdown
ls_notes = "# Notes~n~n- [ ] Call back on Monday"

// The editor colours Markdown ; the viewer shows the page
uo_editor.is_syntax = u_pbt_codeeditor.SYNTAX_MARKDOWN
uo_editor.is_text = ls_notes
uo_md.is_markdown = ls_notes

// ue_changed of uo_editor : the whole recipe
uo_md.is_markdown = uo_editor.is_text

Una tabla de contenidos en una lista #

Para un archivo fijado por is_source, rellene la lista en ue_loaded: antes, el archivo aún se está leyendo.

// Local variables
string ls_titles[], ls_anchors[]
long ll_levels[], ll_i

// ue_loaded of uo_md : one line per heading, indented by its level
lb_toc.Reset()
for ll_i = 1 to uo_md.of_toc(/*titles*/ ls_titles, /*levels*/ ll_levels, /*anchors*/ ls_anchors)
	lb_toc.AddItem(Fill(" ", (ll_levels[ll_i] - 1) * 3) + ls_titles[ll_i])
next

// Local variables
string ls_titles[], ls_anchors[]
long ll_levels[]

// SelectionChanged of lb_toc : bring that heading to the top
uo_md.of_toc(/*titles*/ ls_titles, /*levels*/ ll_levels, /*anchors*/ ls_anchors)
uo_md.of_scroll_to(/*anchor*/ ls_anchors[index])

Una lista de control que el usuario marca #

// Local variables
string ls_text
long ll_at, ll_n

// The user may tick the boxes of the text
uo_md.ib_tasks_editable = true

// ue_task_toggled of uo_md : the start of line al_line of the text
ls_text = uo_md.is_markdown
ll_at = 1
for ll_n = 2 to al_line
	ll_at = Pos(ls_text, "~n", ll_at) + 1
next

// Its box, the first "[" of the line, becomes [x] or [ ]
ll_at = Pos(ls_text, "[", ll_at)
if ab_checked then
	ls_text = Replace(ls_text, ll_at, 3, "[x]")
else
	ls_text = Replace(ls_text, ll_at, 3, "[ ]")
end if

// The text set back : the view keeps its place
uo_md.is_markdown = ls_text

El componente nunca reescribe el texto por sí mismo: la aplicación conserva el control de lo que guarda.

Reabrir un documento donde el lector lo dejó #

// Before closing the window : remember the place in the guide
SetProfileString("acme.ini", "help", "position", uo_md.is_position)

// When the guide is shown again : the place is taken once the file is on screen
uo_md.is_source = "C:\Acme\Help\guide.md"
uo_md.is_position = ProfileString("acme.ini", "help", "position", "")

Buenas prácticas #

• Es un lector, no un editor: para escribir Markdown, ponga al lado un codeeditor en SYNTAX_MARKDOWN, unido por una línea en su ue_changed (ver el ejemplo); el visor conserva su lugar cuando el texto cambia.
• Los enlaces son suyos: nada se abre solo; ue_link_clicked da la dirección, ya resuelta respecto a la carpeta del archivo, y su naturaleza (as_kind) — clasifique por ella, nunca por el texto de la dirección, y nunca ejecute un LINK_FILE sin preguntar.
• Un documento no ejecuta nada: el HTML en bruto se muestra tal como está escrito (o, con ib_allow_html, solo una lista corta de etiquetas inertes), un enlace javascript: sigue siendo texto, una imagen http:// se rechaza, igual que una imagen de un recurso compartido de red (ib_network_pictures) — un documento venido de fuera se muestra sin riesgo.
• Las imágenes: una ruta relativa se lee respecto a la carpeta del archivo (o is_base_path para un texto); para una imagen de la Web, prefiera https://, o descárguela antes (restclient.of_download) y dé su ruta. ib_remote_pictures a false no carga ninguna.
• Un archivo se lee en segundo plano: tras is_source, espere ue_loaded para leer la tabla de contenidos; un ancla y una búsqueda pedidas entretanto esperan al archivo.
• Un documento grande sigue fluido: los primeros bloques aparecen enseguida, el resto en los instantes siguientes; la búsqueda (50.000 apariciones como máximo), of_scroll_to y la impresión esperan a que esté completo.
• De derecha a izquierda: el documento sigue el sentido de la aplicación (listas, citas y tablas se invierten), un bloque de código sigue de izquierda a derecha, y una columna que el autor alineó (:--, --:) conserva su lado.

Heredado de la base común #

Estos miembros existen en todos los componentes visuales — no son propios de este. Se detallan una sola vez, en los capítulos transversales; esta tabla solo dice dónde leerlos.

← Referencia de componentes · Índice de la guía